mirror of
git://git.gnupg.org/gnupg.git
synced 2024-12-22 10:19:57 +01:00
4032aa8be8
* configure.ac (AM_GNU_GETTEXT_VERSION): Bump to 0.18. * po/Makefile.in.in: Upgrade to gettext-0.18. Keep option --previous of msgmerge. * intl/: Upgrade to gettext-0.18. * m4/gettext.m4: Upgrade to gettext-0.18.1. * m4/iconv.m4: Upgrade to gettext-0.18.1. * m4/lib-ld.m4: Upgrade to gettext-0.18.1. * m4/lib-link.m4: Upgrade to gettext-0.18.1. * m4/lib-prefix.m4: Upgrade to gettext-0.18.1. * m4/nls.m4: Upgrade to gettext-0.18.1. * m4/po.m4: Upgrade to gettext-0.18.1. * m4/progtest.m4: Upgrade to gettext-0.18.1. * m4/codeset.m4: Upgrade to gettext-0.18.1. * m4/fcntl-o.m4: New file, from gettext-0.18.1. * m4/glibc2.m4: Upgrade to gettext-0.18.1. * m4/glibc21.m4: Upgrade to gettext-0.18.1. * m4/intdiv0.m4: Upgrade to gettext-0.18.1. * m4/intl.m4: Upgrade to gettext-0.18.1. * m4/intldir.m4: Upgrade to gettext-0.18.1. * m4/intlmacosx.m4: Upgrade to gettext-0.18.1. * m4/intmax.m4: Upgrade to gettext-0.18.1. * m4/inttypes_h.m4: Upgrade to gettext-0.18.1. * m4/inttypes-pri.m4: Upgrade to gettext-0.18.1. * m4/lcmessage.m4: Upgrade to gettext-0.18.1. * m4/lock.m4: Upgrade to gettext-0.18.1. * m4/longlong.m4: Upgrade to gettext-0.18.1. * m4/printf-posix.m4: Upgrade to gettext-0.18.1. * m4/size_max.m4: Upgrade to gettext-0.18.1. * m4/stdint_h.m4: Upgrade to gettext-0.18.1. * m4/threadlib.m4: New file, from gettext-0.18.1. * m4/uintmax_t.m4: Upgrade to gettext-0.18.1. * m4/visibility.m4: Upgrade to gettext-0.18.1. * m4/wchar_t.m4: Upgrade to gettext-0.18.1. * m4/wint_t.m4: Upgrade to gettext-0.18.1. * m4/xsize.m4: Upgrade to gettext-0.18.1. * m4/Makefile.am (EXTRA_DIST): Add the new files.
85 lines
2.3 KiB
Plaintext
85 lines
2.3 KiB
Plaintext
# intdiv0.m4 serial 3 (gettext-0.18)
|
|
dnl Copyright (C) 2002, 2007-2010 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Bruno Haible.
|
|
|
|
AC_DEFUN([gt_INTDIV0],
|
|
[
|
|
AC_REQUIRE([AC_PROG_CC])dnl
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|
|
|
AC_CACHE_CHECK([whether integer division by zero raises SIGFPE],
|
|
gt_cv_int_divbyzero_sigfpe,
|
|
[
|
|
gt_cv_int_divbyzero_sigfpe=
|
|
changequote(,)dnl
|
|
case "$host_os" in
|
|
macos* | darwin[6-9]* | darwin[1-9][0-9]*)
|
|
# On MacOS X 10.2 or newer, just assume the same as when cross-
|
|
# compiling. If we were to perform the real test, 1 Crash Report
|
|
# dialog window would pop up.
|
|
case "$host_cpu" in
|
|
i[34567]86 | x86_64)
|
|
gt_cv_int_divbyzero_sigfpe="guessing yes" ;;
|
|
esac
|
|
;;
|
|
esac
|
|
changequote([,])dnl
|
|
if test -z "$gt_cv_int_divbyzero_sigfpe"; then
|
|
AC_TRY_RUN([
|
|
#include <stdlib.h>
|
|
#include <signal.h>
|
|
|
|
static void
|
|
sigfpe_handler (int sig)
|
|
{
|
|
/* Exit with code 0 if SIGFPE, with code 1 if any other signal. */
|
|
exit (sig != SIGFPE);
|
|
}
|
|
|
|
int x = 1;
|
|
int y = 0;
|
|
int z;
|
|
int nan;
|
|
|
|
int main ()
|
|
{
|
|
signal (SIGFPE, sigfpe_handler);
|
|
/* IRIX and AIX (when "xlc -qcheck" is used) yield signal SIGTRAP. */
|
|
#if (defined (__sgi) || defined (_AIX)) && defined (SIGTRAP)
|
|
signal (SIGTRAP, sigfpe_handler);
|
|
#endif
|
|
/* Linux/SPARC yields signal SIGILL. */
|
|
#if defined (__sparc__) && defined (__linux__)
|
|
signal (SIGILL, sigfpe_handler);
|
|
#endif
|
|
|
|
z = x / y;
|
|
nan = y / y;
|
|
exit (1);
|
|
}
|
|
], [gt_cv_int_divbyzero_sigfpe=yes], [gt_cv_int_divbyzero_sigfpe=no],
|
|
[
|
|
# Guess based on the CPU.
|
|
changequote(,)dnl
|
|
case "$host_cpu" in
|
|
alpha* | i[34567]86 | x86_64 | m68k | s390*)
|
|
gt_cv_int_divbyzero_sigfpe="guessing yes";;
|
|
*)
|
|
gt_cv_int_divbyzero_sigfpe="guessing no";;
|
|
esac
|
|
changequote([,])dnl
|
|
])
|
|
fi
|
|
])
|
|
case "$gt_cv_int_divbyzero_sigfpe" in
|
|
*yes) value=1;;
|
|
*) value=0;;
|
|
esac
|
|
AC_DEFINE_UNQUOTED([INTDIV0_RAISES_SIGFPE], [$value],
|
|
[Define if integer division by zero raises signal SIGFPE.])
|
|
])
|