security-and-privacy/gnupg
security-and-privacy/gnupg
1
0
Fork 0
mirror of git://git.gnupg.org/gnupg.git synced 2025-07-03 22:56:33 +02:00
Code Activity

Not yet completed changes to support PPC

Browse source
This commit is contained in:
Werner Koch 1998-11-10 18:35:11 +00:00
parent b076ce3021
commit 95217d480d
20 changed files with 733 additions and 44 deletions
Download patch file Download diff file Expand all files Collapse all files

8
mpi/powerpc32/distfiles Normal file
View file

@ -0,0 +1,8 @@
mpih-add1.S
mpih-sub1.S
mpih-mul1.S
mpih-mul2.S
mpih-mul3.S
mpih-lshift.S
mpih-rshift.S

60
mpi/powerpc32/mpih-add1.S Normal file
View file

@ -0,0 +1,60 @@
/* PowerPC-32 add_n -- Add two limb vectors of equal, non-zero length.
*
* Copyright (C) 1992, 1994, 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_add_n( mpi_ptr_t res_ptr, (r3)
* mpi_ptr_t s1_ptr, (r4)
* mpi_ptr_t s2_ptr, (r5)
* mpi_size_t size) (r6)
*/
.toc
.extern mpihelp_add_n[DS]
.extern .mpihelp_add_n
.csect [PR]
.align 2
.globl mpihelp_add_n
.globl .mpihelp_add_n
.csect mpihelp_add_n[DS]
mpihelp_add_n:
.long .mpihelp_add_n, TOC[tc0], 0
.csect [PR]
.mpihelp_add_n:
mtctr 6 # copy size into CTR
lwz 8,0(4) # load least significant s1 limb
lwz 0,0(5) # load least significant s2 limb
addi 3,3,-4 # offset res_ptr, it's updated before used
addc 7,0,8 # add least significant limbs, set cy
bdz Lend # If done, skip loop
Loop: lwzu 8,4(4) # load s1 limb and update s1_ptr
lwzu 0,4(5) # load s2 limb and update s2_ptr
stwu 7,4(3) # store previous limb in load latency slot
adde 7,0,8 # add new limbs with cy, set cy
bdnz Loop # decrement CTR and loop back
Lend: stw 7,4(3) # store ultimate result limb
li 3,0 # load cy into ...
addze 3,3 # ... return value register
blr

71
mpi/powerpc32/mpih-lshift.S Normal file
View file

@ -0,0 +1,71 @@
/* PowerPC-32 lshift
*
* Copyright (C) 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_lshift( mpi_ptr_t wp, (r3)
* mpi_ptr_t up, (r4)
* mpi_size_t usize, (r5)
* unsigned cnt) (r6)
*/
.toc
.csect .text[PR]
.align 2
.globl mpihelp_lshift
.globl .mpihelp_lshift
.csect mpihelp_lshift[DS]
mpihelp_lshift:
.long .mpihelp_lshift, TOC[tc0], 0
.csect .text[PR]
.mpihelp_lshift:
mtctr 5 # copy size into CTR
slwi 0,5,2
add 7,3,0 # make r7 point at end of res
add 4,4,0 # make r4 point at end of s1
subfic 8,6,32
lwzu 11,-4(4) # load first s1 limb
srw 3,11,8 # compute function return value
bdz Lend1
Loop: lwzu 10,-4(4)
slw 9,11,6
srw 12,10,8
or 9,9,12
stwu 9,-4(7)
bdz Lend2
lwzu 11,-4(4)
slw 9,10,6
srw 12,11,8
or 9,9,12
stwu 9,-4(7)
bdnz Loop
Lend1: slw 0,11,6
stw 0,-4(7)
blr
Lend2: slw 0,10,6
stw 0,-4(7)
blr

67
mpi/powerpc32/mpih-mul1.S Normal file
View file

@ -0,0 +1,67 @@
/* PowerPC-32 mul_1 -- Multiply a limb vector with a limb and store
* the result in a second limb vector.
*
* Copyright (C) 1993, 1994, 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_mul_1( mpi_ptr_t res_ptr, (r3)
* mpi_ptr_t s1_ptr, (r4)
* mpi_size_t s1_size, (r5)
* mpi_limb_t s2_limb) (r6)
*
* This is a fairly straightforward implementation. The timing of the PC601
* is hard to understand, so I will wait to optimize this until I have some
* hardware to play with.
*
* The code trivially generalizes to 64 bit limbs for the PC620.
*/
.toc
.csect .mpihelp_mul_1[PR]
.align 2
.globl mpihelp_mul_1
.globl .mpihelp_mul_1
.csect mpihelp_mul_1[DS]
mpihelp_mul_1:
.long .mpihelp_mul_1[PR], TOC[tc0], 0
.csect .mpihelp_mul_1[PR]
.mpihelp_mul_1:
mtctr 5
lwz 0,0(4)
mullw 7,0,6
mulhwu 10,0,6
addi 3,3,-4 # adjust res_ptr
addic 5,5,0 # clear cy with dummy insn
bdz Lend
Loop: lwzu 0,4(4)
stwu 7,4(3)
mullw 8,0,6
adde 7,8,10
mulhwu 10,0,6
bdnz Loop
Lend: stw 7,4(3)
addze 3,10
blr

73
mpi/powerpc32/mpih-mul2.S Normal file
View file

@ -0,0 +1,73 @@
/* PowerPC-32 addmul_1 -- Multiply a limb vector with a limb and add
* the result to a second limb vector.
* Copyright (C) 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_addmul_1( mpi_ptr_t res_ptr, (r3)
* mpi_ptr_t s1_ptr, (r4)
* mpi_size_t s1_size, (r5)
* mpi_limb_t s2_limb) (r6)
*
* This is a fairly straightforward implementation. The timing of the PC601
* is hard to understand, so I will wait to optimize this until I have some
* hardware to play with.
*
* The code trivially generalizes to 64 bit limbs for the PC620.
*/
.toc
.csect .mpihelp_addmul_1[PR]
.align 2
.globl mpihelp_addmul_1
.globl .mpihelp_addmul_1
.csect mpihelp_addmul_1[DS]
mpihelp_addmul_1:
.long .mpihelp_addmul_1[PR], TOC[tc0], 0
.csect .mpihelp_addmul_1[PR]
.mpihelp_addmul_1:
mtctr 5
lwz 0,0(4)
mullw 7,0,6
mulhwu 10,0,6
lwz 9,0(3)
addc 8,7,9
addi 3,3,-4
bdz Lend
Loop: lwzu 0,4(4)
stwu 8,4(3)
mullw 8,0,6
adde 7,8,10
mulhwu 10,0,6
lwz 9,4(3)
addze 10,10
addc 8,7,9
bdnz Loop
Lend: stw 8,4(3)
addze 3,10
blr

74
mpi/powerpc32/mpih-mul3.S Normal file
View file

@ -0,0 +1,74 @@
/* PowerPC-32 submul_1 -- Multiply a limb vector with a limb and subtract
* the result from a second limb vector.
*
* Copyright (C) 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_submul_1( mpi_ptr_t res_ptr, (r3)
* mpi_ptr_t s1_ptr, (r4)
* mpi_size_t s1_size, (r5)
* mpi_limb_t s2_limb) (r6)
*
* This is a fairly straightforward implementation. The timing of the PC601
* is hard to understand, so I will wait to optimize this until I have some
* hardware to play with.
*
* The code trivially generalizes to 64 bit limbs for the PC620.
*/
.toc
.csect .mpihelp_submul_1[PR]
.align 2
.globl mpihelp_submul_1
.globl .mpihelp_submul_1
.csect mpihelp_submul_1[DS]
mpihelp_submul_1:
.long .mpihelp_submul_1[PR], TOC[tc0], 0
.csect .mpihelp_submul_1[PR]
.mpihelp_submul_1:
mtctr 5
lwz 0,0(4)
mullw 7,0,6
mulhwu 10,0,6
lwz 9,0(3)
subfc 8,7,9
addc 7,7,8 # invert cy (r7 is junk)
addi 3,3,-4
bdz Lend
Loop: lwzu 0,4(4)
stwu 8,4(3)
mullw 8,0,6
adde 7,8,10
mulhwu 10,0,6
lwz 9,4(3)
addze 10,10
subfc 8,7,9
addc 7,7,8 # invert cy (r7 is junk)
bdnz Loop
Lend: stw 8,4(3)
addze 3,10
blr

68
mpi/powerpc32/mpih-rshift.S Normal file
View file

@ -0,0 +1,68 @@
/* PowerPC-32 rshift
*
* Copyright (C) 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_rshift( mpi_ptr_t wp, (r3)
* mpi_ptr_t up, (r4)
* mpi_size_t usize, (r5)
* unsigned cnt) (r6)
*/
.toc
.csect .text[PR]
.align 2
.globl mpihelp_rshift
.globl .mpihelp_rshift
.csect mpihelp_rshift[DS]
mpihelp_rshift:
.long .mpihelp_rshift, TOC[tc0], 0
.csect .text[PR]
.mpihelp_rshift:
mtctr 5 # copy size into CTR
addi 7,3,-4 # move adjusted res_ptr to free return reg
subfic 8,6,32
lwz 11,0(4) # load first s1 limb
slw 3,11,8 # compute function return value
bdz Lend1
Loop: lwzu 10,4(4)
srw 9,11,6
slw 12,10,8
or 9,9,12
stwu 9,4(7)
bdz Lend2
lwzu 11,4(4)
srw 9,10,6
slw 12,11,8
or 9,9,12
stwu 9,4(7)
bdnz Loop
Lend1: srw 0,11,6
stw 0,4(7)
blr
Lend2: srw 0,10,6
stw 0,4(7)
blr

60
mpi/powerpc32/mpih-sub1.S Normal file
View file

@ -0,0 +1,60 @@
/* PowerPC-32 sub_n -- Subtract two limb vectors of the same length > 0
* and store difference in a third limb vector.
*
* Copyright (C) 1992, 1994, 1995, 1998 Free Software Foundation, Inc.
*
* This file is part of GnuPG.
*
* GnuPG is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* GnuPG is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
*/
/*******************
* mpi_limb_t
* mpihelp_sub_n( mpi_ptr_t res_ptr, (r3)
* mpi_ptr_t s1_ptr, (r4)
* mpi_ptr_t s2_ptr, (r5)
* mpi_size_t size) (r6)
*/
.toc
.extern mpihelp_sub_n[DS]
.extern .mpihelp_sub_n
.csect [PR]
.align 2
.globl mpihelp_sub_n
.globl .mpihelp_sub_n
.csect mpihelp_sub_n[DS]
mpihelp_sub_n:
.long .mpihelp_sub_n, TOC[tc0], 0
.csect [PR]
.mpihelp_sub_n:
mtctr 6 # copy size into CTR
lwz 8,0(4) # load least significant s1 limb
lwz 0,0(5) # load least significant s2 limb
addi 3,3,-4 # offset res_ptr, it's updated before used
subfc 7,0,8 # add least significant limbs, set cy
bdz Lend # If done, skip loop
Loop: lwzu 8,4(4) # load s1 limb and update s1_ptr
lwzu 0,4(5) # load s2 limb and update s2_ptr
stwu 7,4(3) # store previous limb in load latency slot
subfe 7,0,8 # add new limbs with cy, set cy
bdnz Loop # decrement CTR and loop back
Lend: stw 7,4(3) # store ultimate result limb
subfe 3,0,0 # load !cy into ...
subfic 3,3,0 # ... return value register
blr