mirror of git://git.gnupg.org/gnupg.git
76 lines
2.9 KiB
Plaintext
76 lines
2.9 KiB
Plaintext
|
dnl Autoconf macros for libgcrypt
|
||
|
|
dnl Copyright (C) 2002 Free Software Foundation, Inc.
|
||
|
|
dnl
|
||
|
|
dnl This file is free software; as a special exception the author gives
|
||
|
|
dnl unlimited permission to copy and/or distribute it, with or without
|
||
|
|
dnl modifications, as long as this notice is preserved.
|
||
|
|
dnl
|
||
|
|
dnl This file is distributed in the hope that it will be useful, but
|
||
|
|
dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
|
||
|
|
dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||
|
|
|
||
|
|
|
||
|
|
dnl AM_PATH_LIBGCRYPT([MINIMUM-VERSION,
|
||
|
|
dnl [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
|
||
|
|
dnl Test for liblibgcrypt and define LIBGCRYPT_CFLAGS and LIBGCRYPT_LIBS
|
||
|
|
dnl
|
||
|
|
AC_DEFUN(AM_PATH_LIBGCRYPT,
|
||
|
|
[ AC_ARG_WITH(libgcrypt-prefix,
|
||
|
|
AC_HELP_STRING([--with-libgcrypt-prefix=PFX],
|
||
|
|
[prefix where LIBGCRYPT is installed (optional)]),
|
||
|
|
libgcrypt_config_prefix="$withval", libgcrypt_config_prefix="")
|
||
|
|
if test x$libgcrypt_config_prefix != x ; then
|
||
|
|
if test x${LIBGCRYPT_CONFIG+set} != xset ; then
|
||
|
|
LIBGCRYPT_CONFIG=$libgcrypt_config_prefix/bin/libgcrypt-config
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
|
||
|
|
AC_PATH_PROG(LIBGCRYPT_CONFIG, libgcrypt-config, no)
|
||
|
|
min_libgcrypt_version=ifelse([$1], ,0.4.4,$1)
|
||
|
|
AC_MSG_CHECKING(for LIBGCRYPT - version >= $min_libgcrypt_version)
|
||
|
|
ok=no
|
||
|
|
if test "$LIBGCRYPT_CONFIG" != "no" ; then
|
||
|
|
req_major=`echo $min_libgcrypt_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
|
||
|
|
req_minor=`echo $min_libgcrypt_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
|
||
|
|
req_micro=`echo $min_libgcrypt_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
|
||
|
|
libgcrypt_config_version=`$LIBGCRYPT_CONFIG $libgcrypt_config_args --version`
|
||
|
|
major=`echo $libgcrypt_config_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
|
||
|
|
minor=`echo $libgcrypt_config_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
|
||
|
|
micro=`echo $libgcrypt_config_version | \
|
||
|
|
sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
|
||
|
|
if test "$major" -gt "$req_major"; then
|
||
|
|
ok=yes
|
||
|
|
else
|
||
|
|
if test "$major" -eq "$req_major"; then
|
||
|
|
if test "$minor" -gt "$req_minor"; then
|
||
|
|
ok=yes
|
||
|
|
else
|
||
|
|
if test "$minor" -eq "$req_minor"; then
|
||
|
|
if test "$micro" -ge "$req_micro"; then
|
||
|
|
ok=yes
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
fi
|
||
|
|
if test $ok = yes; then
|
||
|
|
LIBGCRYPT_CFLAGS=`$LIBGCRYPT_CONFIG $libgcrypt_config_args --cflags`
|
||
|
|
LIBGCRYPT_LIBS=`$LIBGCRYPT_CONFIG $libgcrypt_config_args --libs`
|
||
|
|
AC_MSG_RESULT(yes)
|
||
|
|
ifelse([$2], , :, [$2])
|
||
|
|
else
|
||
|
|
LIBGCRYPT_CFLAGS=""
|
||
|
|
LIBGCRYPT_LIBS=""
|
||
|
|
AC_MSG_RESULT(no)
|
||
|
|
ifelse([$3], , :, [$3])
|
||
|
|
fi
|
||
|
|
AC_SUBST(LIBGCRYPT_CFLAGS)
|
||
|
|
AC_SUBST(LIBGCRYPT_LIBS)
|
||
|
|
])
|