dev-ruby/asciidoctor-pdf: Import package from ::guru

Signed-off-by: Nils Freydank <nils.freydank@posteo.de>

dev-ruby/asciidoctor-pdf/Manifest

@@ -0,0 +1 @@
+DIST asciidoctor-pdf-2.3.12.tar.gz 6558252 BLAKE2B 0e789496e23b558a44423547a834686ea0a99e55df244e208cbdf4bfce83ff0bd27949fd3c81f496e7f163519e6d0d932c584f5871e23c1a76a0e20ee1f2ed76 SHA512 889ee21a6b8d709983da8c9bbbc456add20f235634f6f63bfed0a0497bd10ca7337b48762c91a477a8017598bf201c4418cefb76482fb0c786ab6784e302d068

dev-ruby/asciidoctor-pdf/asciidoctor-pdf-2.3.12.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.adoc README.adoc"
+RUBY_FAKEGEM_EXTRAINSTALL="data"
+RUBY_FAKEGEM_GEMSPEC="asciidoctor-pdf.gemspec"
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A native PDF converter for AsciiDoc based on Asciidoctor and Prawn"
+HOMEPAGE="https://github.com/asciidoctor/asciidoctor-pdf"
+SRC_URI="https://github.com/asciidoctor/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="test? ( app-text/poppler )"
+
+ruby_add_rdepend "
+	>=dev-ruby/asciidoctor-2.0
+	>=dev-ruby/concurrent-ruby-1.1
+	>=dev-ruby/matrix-0.4
+	>=dev-ruby/prawn-2.4.0
+	>=dev-ruby/prawn-icon-3.0.0
+	>=dev-ruby/prawn-svg-0.32.0
+	>=dev-ruby/prawn-table-0.2.0
+	>=dev-ruby/prawn-templates-0.1.0
+	>=dev-ruby/treetop-1.6.0
+	"
+ruby_add_bdepend "test? (
+	>=dev-ruby/chunky_png-1.4.0
+	>=dev-ruby/coderay-1.1.0
+	>=dev-ruby/pdf-inspector-1.3.0
+)"
+
+all_ruby_prepare() {
+	rm Gemfile || die
+
+	sed -i -e "s:_relative ': './:" ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+}
+
+each_ruby_test() {
+	RSPEC_VERSION=3 ruby-ng_rspec -t ~network -t ~visual spec
+}

dev-ruby/asciidoctor-pdf/metadata.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>vowstar@gmail.com</email>
+		<name>Huang Rui</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">asciidoctor/asciidoctor-pdf</remote-id>
+	</upstream>
+	<longdescription lang="en">
+		Asciidoctor PDF is a native PDF converter for AsciiDoc that serves the
+		pdf backend. It bypasses the step of generating an intermediary format
+		such as DocBook, Apache FO, or LaTeX in order to produce PDF.
+		Instead, you use Asciidoctor PDF to convert your documents directly
+		from AsciiDoc to PDF with Asciidoctor. The aim of this library is to
+		take the pain out of creating PDF documents from AsciiDoc.
+	</longdescription>
+</pkgmetadata>