sci-libs/dcmtk: version bump 3.6.4

https://github.com/gentoo/gentoo/pull/12024

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Horea Christian <chr@chymera.eu>

sci-libs/dcmtk/ChangeLog

@@ -0,0 +1,5 @@
+*dcmtk-3.6.4 (16 May 2019)
+
+  16 May 2019;  <chymera@gentoo.org> +dcmtk-3.6.4.ebuild, +metadata.xml:
+  sci-libs/dcmtk: version bump 3.6.4 ahead of gentoo
+  https://github.com/gentoo/gentoo/pull/12024

sci-libs/dcmtk/Manifest

@@ -0,0 +1 @@
+DIST dcmtk-3.6.4.tar.gz 6402734 SHA256 a93ff354fae091689a0740a1000cde7d4378fdf733aef9287a70d7091efa42c0 SHA512 735f85d04410437a5163b154f43c8a299aff7a8f810605ce6c5027ae4569ff1323a69f70a2603805cec9d826a31166fd904bb53c3edc1137bfc41ba2902c2261 WHIRLPOOL a9bb063c2a19ec95b92bce33b2710108e8636601a209df3ee3d5127e8a1a82b54de29ef1c5aa747a1be7314ea81dcc993b7d74bd13095fc441f228e809c6f5d5

sci-libs/dcmtk/dcmtk-3.6.4.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="The DICOM Toolkit"
+HOMEPAGE="https://dicom.offis.de/dcmtk.php.en"
+SRC_URI="ftp://dicom.offis.de/pub/dicom/offis/software/${PN}/${PN}363/${P}.tar.gz"
+
+LICENSE="OFFIS"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="doc png ssl tcpd tiff +threads xml zlib"
+
+RDEPEND="
+	dev-libs/icu:=
+	virtual/jpeg:0
+	png? ( media-libs/libpng:* )
+	ssl? ( dev-libs/openssl:0= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	tiff? ( media-libs/tiff:0 )
+	xml? ( dev-libs/libxml2:2 )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	media-gfx/graphviz
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -e "s:share/doc/dcmtk:&-${PV}:" \
+		-e "s:DIR \"/:DIR \"/usr/:" \
+		-e "s:usr/etc:etc:" \
+		-e "s:/lib\":/$(get_libdir)\":" \
+		-e "s:COPYRIGHT::" \
+		-i CMakeLists.txt || die
+	sed -e 's:${CMAKE_INSTALL_PREFIX}/::' \
+		-i dcmwlm/data/CMakeLists.txt doxygen/CMakeLists.txt || die
+	# Temporary workaround: docs are not built with CMake
+	sed -i -e '/include/d' doxygen/Makefile.in || die
+
+	# fix -D deprecation warnings
+	sed -i -e "s|_BSD_SOURCE|_DEFAULT_SOURCE|g" \
+		"${S}"/config/configure.in \
+		"${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DDCMTK_WITH_ICU=ON
+		-DDCMTK_WITH_TIFF=$(usex tiff)
+		-DDCMTK_WITH_PNG=$(usex png)
+		-DDCMTK_WITH_XML=$(usex xml)
+		-DDCMTK_WITH_ZLIB=$(usex zlib)
+		-DDCMTK_WITH_OPENSSL=$(usex ssl)
+		-DDCMTK_WITH_DOXYGEN=$(usex doc)
+		-DDCMTK_WITH_THREADS=$(usex threads)
+	)
+
+	cmake-utils_src_configure
+
+	if use doc; then
+		cd "${S}"/doxygen || die
+		econf
+	fi
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		emake -C "${S}"/doxygen
+	fi
+}
+
+src_install() {
+	doman doxygen/manpages/man1/*
+
+	if use doc; then
+		local HTML_DOCS=( "${S}"/doxygen/htmldocs/. )
+	fi
+	cmake-utils_src_install
+}

sci-libs/dcmtk/metadata.xml

@@ -0,0 +1,22 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sci@gentoo.org</email>
+		<name>Gentoo Science Project</name>
+	</maintainer>
+	<longdescription lang="en">
+DCMTK is a collection of libraries and applications implementing large
+parts the DICOM standard. It includes software for examining,
+constructing and converting DICOM image files, handling offline media,
+sending and receiving images over a network connection, as well as
+demonstrative image storage and worklist servers.
+</longdescription>
+	<longdescription lang="fr">
+DCMTK est un ensemble de bibliothèques et d'application implémentant
+une grande partie du standard DICOM. Cela comprend des logiciels de
+visualisation et de conversion des fichier image, de manipulation de
+médias locaux, de réception et d'envoi d'images à travers un réseau
+ainsi qu'un serveur d'images et de worklist de demonstration.
+</longdescription>
+</pkgmetadata>