diff --git a/dev-python/statsmodels/ChangeLog b/dev-python/statsmodels/ChangeLog
new file mode 100644
index 0000000..5bab2b2
--- /dev/null
+++ b/dev-python/statsmodels/ChangeLog
@@ -0,0 +1,4 @@
+*statsmodels-9999 (08 Nov 2017)
+
+  08 Nov 2017;  <chymera@gentoo.org> +metadata.xml, +statsmodels-9999.ebuild:
+  dev-python/statsmodels: New ebuild
diff --git a/dev-python/statsmodels/metadata.xml b/dev-python/statsmodels/metadata.xml
new file mode 100644
index 0000000..cb9b897
--- /dev/null
+++ b/dev-python/statsmodels/metadata.xml
@@ -0,0 +1,26 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    statsmodels is a Python module that allows users to explore data,
+    estimate statistical models, and perform statistical tests. An
+    extensive list of descriptive statistics, statistical tests,
+    plotting functions, and result statistics are available for
+    different types of data and each estimator. Researchers across
+    fields may find that statsmodels fully meets their needs for
+    statistical computing and data analysis in Python.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">statsmodels</remote-id>
+    <remote-id type="github">statsmodels</remote-id>
+    <remote-id type="sourceforge">statsmodels</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-python/statsmodels/statsmodels-9999.ebuild b/dev-python/statsmodels/statsmodels-9999.ebuild
new file mode 100644
index 0000000..27569b4
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-9999.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 git-r3 virtualx
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="http://www.statsmodels.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/statsmodels/statsmodels.git"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+CDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+RDEPEND="${CDEPEND}
+	examples? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+DEPEND="${CDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "/sphinx.ext.intersphinx/d" -i docs/source/conf.py || die
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	export HOME="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx -b html --build-dir=docs/build
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	virtx nosetests -v || die
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	use doc && HTML_DOCS=( docs/build/html/* )
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}