diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
new file mode 100644
index 0000000..66f381e
--- /dev/null
+++ b/dev-python/graph-tool/Manifest
@@ -0,0 +1 @@
+DIST graph-tool-2.19.tar.bz2 15147961 SHA256 eba1090f94b0434890beedaf0c100dd0fc77e41ebfe29b4725d76cadb82099af SHA512 dc0bd93ccf21bb6616035dbfe33b0d9406eb894791e615795d486dc8f9d9991a6b93cf835cf4e59197005c14faedf105f3384cccd42db544104840cf857b2a84 WHIRLPOOL 3a398c98487a1e29952fea4c3ff8671e5aaf3d4f9e8df26aae9f6a856e61c290954f4c662e48ae424cbe0b916833a8f3bc7a6eefe6c6c3a08540de58ed6b9de0
diff --git a/dev-python/graph-tool/graph-tool-2.19.ebuild b/dev-python/graph-tool/graph-tool-2.19.ebuild
new file mode 100644
index 0000000..cee02ef
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.19.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit check-reqs toolchain-funcs python-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="http://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="http://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+
+# Bug #536734; configure sets boostlib 1.53.0 but 1.54.0 is required
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/boost-1.54.0[python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	>=sci-mathematics/cgal-3.5
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash
+	virtual/pkgconfig"
+
+# most machines don't have enough ram for parallel builds
+MAKEOPTS="${MAKEOPTS} -j1"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+	check-reqs_pkg_pretend
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+	>py-compile
+	python_copy_sources
+}
+
+src_configure() {
+	local threads
+	has_version dev-libs/boost[threads] && threads="-mt"
+
+	configure() {
+		econf \
+			--disable-static \
+			--disable-optimization \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="${EPYTHON: -3}${threads}"
+	}
+	python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	prune_libtool_files --modules
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null
+	"$@"
+	popd > /dev/null
+}