diff --git a/dev-tex/pythontex/ChangeLog b/dev-tex/pythontex/ChangeLog
new file mode 100644
index 0000000..22c73d5
--- /dev/null
+++ b/dev-tex/pythontex/ChangeLog
@@ -0,0 +1,6 @@
+*pythontex-0.17 (17 Feb 2020)
+*pythontex-9999 (17 Feb 2020)
+
+  17 Feb 2020;  <chymera@gentoo.org> +metadata.xml, +pythontex-0.17.ebuild,
+  +pythontex-9999.ebuild:
+  dev-tex/pythontex: version bump ahead of Gentoo Main
diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
new file mode 100644
index 0000000..583b623
--- /dev/null
+++ b/dev-tex/pythontex/Manifest
@@ -0,0 +1 @@
+DIST pythontex-0.17.tar.gz 1800631 SHA256 e5b1419c2a3a994f15768208b5e4df9970f238c96e37660bc7d45015109509ce SHA512 ac248579f8645c225839ca9698b6193d2a7d8360a50e9a8406fae5616f54418a173635d1c2e8c47b18e85cdd1fa1e81c9435169c44f06fb19505c280f9bbaee5 WHIRLPOOL 8369e52a459252fd178ea89adec1b20eb6f303bd26216c9771f3b7ff19921d15c27adccae9ff26362ccd2488181cecdacd5595312cbb6d7692f70039808cba85
diff --git a/dev-tex/pythontex/metadata.xml b/dev-tex/pythontex/metadata.xml
new file mode 100644
index 0000000..8d0ea9e
--- /dev/null
+++ b/dev-tex/pythontex/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sci@gentoo.org</email>
+		<name>Gentoo Science Project</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>chr@chymera.eu</email>
+		<name>Horea Christian</name>
+	</maintainer>
+	<use>
+		<flag name="highlighting">enable code highlight</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">gpoore/pythontex</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-tex/pythontex/pythontex-0.17.ebuild b/dev-tex/pythontex/pythontex-0.17.ebuild
new file mode 100644
index 0000000..875e14c
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.17.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS="~amd64"
+IUSE="highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	dev-texlive/texlive-latex
+	"
+RDEPEND="${DEPEND}
+	dev-texlive/texlive-latexextra
+	highlighting? ( dev-python/pygments[${PYTHON_USEDEP}] )
+	"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc ${PN}/README "${S}"/*rst ${PN}_quickstart/*
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall dtx ins sty
+}
diff --git a/dev-tex/pythontex/pythontex-9999.ebuild b/dev-tex/pythontex/pythontex-9999.ebuild
new file mode 100644
index 0000000..e9d3f47
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-9999.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit latex-package python-r1 git-r3
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/gpoore/pythontex.git"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS=""
+IUSE="highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	dev-texlive/texlive-latex
+	"
+RDEPEND="${DEPEND}
+	dev-texlive/texlive-latexextra
+	highlighting? ( dev-python/pygments[${PYTHON_USEDEP}] )
+	"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc ${PN}/README "${S}"/*rst ${PN}_quickstart/*
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall dtx ins sty
+}